Elektronika, ukázky pro STM8S103F3, plus programování v assembleru.

Radiopřijímač s modulem TEA5767 Y4

ovládaný pomocí dálkového infra ovladače

Ukázka řízení modulu radiopříjímače TEA5767 přes sběrnici i2c. Zde je modul ovládán pomocí infračerveného čidla, ale určitě není problém to předělat na ovládání pomocí několika tlačítek. V ukázce níže je ovládání zapnutí/vypnutí a pomocí šipek ladění vpřed/zpět, a to hrubě a jemně. Výstup z modulu rádia je sluchátkový a modul nedisponuje žádným řízením hlasitosti. Předpokládá se připojení (stereo) zesilovače, s potenciometry.
Ovládání modulu přes infra je patrné ze adrojáku. Snažil jsem se o co největší jednoduchost, proto jsem se omezil pouze na ladění, zapnutí a vypnutí. Šipky nahoru / dolů, jsou ladění hrubě a šipky vpravo / vlevo je ladění jemně. Tlačítkem OK se modul zapíná a tlačítkem "hash" se vypíná. Hvězdička uloží do eeprom právě naladěnou stanici a kterékoliv číslo ji pak vyvolá.

Propojení modulů je velmi jednoduché, kromě napájení; infračidlo potřebuje jediný datový vodič a i2c dva (scl, sda). K napájení použijte konektor mikro USB, který je na desce mikrokontroléru. Infra i modul TDA5767 je napájen z pinu 3,3V.
Ve fragmentech zdrojáku níže je klíčová část vlastní komunikace s TEA5767. Jsou to tea5767w pro zápis do modulu a tea5767r pro čtení z něj. Adresa modulu na i2c sběrnici je 0x60.
Trochu složitější je zadávání kmitočtů, tento se nezadává v MHz, ani kHz, ale musí se vypočítat hodnota pro interní děličku (PLL). Vzorec pro její výpočet vypadá nějak takto:

      4 × (Frf + Fif)                            4 x (98.2 + 0.225) 
PLL = -----------------  například pro 98.2 MHz: -------------------  = 12 015 (0x2EEF)
            Fref                                      0.032768

Frf = požadovaná frekvence (v MHz)
Fif = mezifrekvence, obvykle 225 kHz (0.225 MHz)
Fref = referenční krok ladění, 32.768 kHz (0.032768 MHz)
výsledek se zaokrouhlí na celé číslo

rutina pro zápis, v registru "Y" je PLL pro kmitočet rozhlasové stanice (ladění)

...

tea5767w      ;zapise pres i2c - 5 bajtu do TEA5767 v Y je ladeni
               bset   I2C_CR2, #0
_startw        btjf   I2C_SR1, #0, _startw   ;start spusten
               ld     a, #TEA5767_ADR        ;0x60 
               sll    a                      ;adresa pro zapis
               ld     I2C_DR, a 
_waitaddrw     btjf   I2C_SR1, #1, _waitaddrw  ;cekat na ADDR               
               ld     a, I2C_SR3             ;dummy read kvuli clear ADDR   
               ld     a, yh                  ;1.byte ladeni 1
               ld     I2C_DR, a              
_wtx1          btjf   I2C_SR1, #7, _wtx1     
               ld     a, yl                  ;2.byte ladeni 2
               ld     I2C_DR, a
_wtx2          btjf   I2C_SR1, #7, _wtx2
               mov    I2C_DR, #$08           ;3.byte 0x08=mono / 0=stereo
_wtx3          btjf   I2C_SR1, #7, _wtx3
               mov    I2C_DR, #$10           ;4.byte xtal
_wtx4          btjf   I2C_SR1, #7, _wtx4
               clr    I2C_DR                 ;5.byte default
_wtx5          btjf   I2C_SR1, #7, _wtx5
               bset   I2C_CR2, #1            ;i2c stop transakce
               ret
...

rutina pro čtení

...

radio1         ds.b     1   ;pro cteni z TEA5767
radio2         ds.b     1
radio3         ds.b     1
radio4         ds.b     1
radio5         ds.b     1

...

tea5767r      ;precte pres i2c - 5 bajtu 
               bset   I2C_CR2, #0
_startr        btjf   I2C_SR1, #0, _startr   ;start spusten
               ld     a, #TEA5767_ADR        ;0x60 
               sll    a
               or     a, #1                  ;adresa pro cteni
               ld     I2C_DR, a 
_waitaddrr     btjf   I2C_SR1, #1, _waitaddrr ;cekat na ADDR               
               ld     a, I2C_SR3              ;dummy read kvuli clear ADDR   
               bset   I2C_CR2, #2             ;ACK=1               
_wb1           btjf   I2C_SR1, #6, _wb1       ;cte 1.byte
               mov    radio1, I2C_DR
_wb2           btjf   I2C_SR1, #6, _wb2       ;cte 2.byte
               mov    radio2, I2C_DR
_wb3           btjf   I2C_SR1, #6, _wb3       ;cte 3.byte
               mov    radio3, I2C_DR
_wb4           btjf   I2C_SR1, #6, _wb4       ;cte 4.byte
               mov    radio4, I2C_DR
               bres   I2C_CR2, #2             ;nasleduje posledni bajt, ACK=0 (NACK)
               bset   I2C_CR2, #1             ;STOP=1
_wb5           btjf   I2C_SR1, #6, _wb5
               mov    radio5, I2C_DR          ;cte 5.byte               
               ret
...

Modul TEA5767 nebsahuje žádné i2c registry, prostě se na sběrnici přímo odešle pět bajtů a zase se z ní může číst. Tím se celá komunikace zjednodušuje. Význam jednotlvých bajtů je popsán v datasheetu TEA5767 Vlastní program i s infra ovladačem a řízením TDA5767 zabírá 692 bajtů. V úspornosti je assembler prostě nepřekonatelný :-)

Celý zdroják je zde:

stm8/

              .form 64
              .tab 10,8,18,60
               TITLE "STM8"

              #include "mapping.inc"

ram0_start.b   equ  $ram0_segment_start
ram0_end.b     equ  $ram0_segment_end
ram1_start.w   equ  $ram1_segment_start
ram1_end.w     equ  $ram1_segment_end	
stack_start.w  equ  $stack_segment_start 
stack_end.w    equ  $stack_segment_end

;-------------------------------------------------------------

CLK_CKDIVR     equ  $50C6 ;pouzite syst.registry CPU rychlost
FLASH_DUKR     equ  $5064 ;EEPEOM
FLASH_IAPSR    equ  $505F
I2C_CR1        equ  $5210 ;adresy registru i2c
I2C_CR2        equ  $5211
I2C_FREQR      equ  $5212
I2C_OARL       equ  $5213
I2C_OARH       equ  $5214
I2C_DR         equ  $5216
I2C_SR1        equ  $5217
I2C_SR2        equ  $5218
I2C_SR3        equ  $5219
I2C_CCRL       equ  $521B
I2C_CCRH       equ  $521C
I2C_TRISER     equ  $521D
PA_ODR         equ  $5000 ;PA1 infra
PA_IDR         equ  $5001
PA_DDR         equ  $5002
PA_CR1         equ  $5003
PA_CR2         equ  $5004
EXTI_CR1       equ  $50A0
EXTI_CR2       equ  $50A1

PIN_INFRA      equ  1
TEA5767_ADR    equ  $60   ;i2c adresa radio modulu
HRANICE_0_1    equ  $02   ;co je mene je nula, vice, nebo rovno jednicka
INFRA_START    equ  $0B00 ;delka start impulzu infra
INFRA          equ  0     ;priznakove bity
NEC_VALID      equ  7     ;nahazuje bit 7, pokud je infra platny
DOLNI          equ  10647 ;dolni okraj pasma
HORNI          equ  13211 ;horni okraj pasma  +2564

;-- RAM promenne-----------------------------------------------
               segment 'ram0'

raw_infra      ds.b     32  ;raw data z infra
infra_long     ds.b     3   ;nactena hodnota z infra
infra_kod      ds.b     1   ;kod infra
raw_cnt        ds.b     1
rbyte3         ds.b     1   ;byte pro rizeni TEA5767
rbyte4         ds.b     1
naladeno       ds.w     1   ;naladena fq
priznaky       ds.b     1  
radio1         ds.b     1   ;pro cteni z TEA5767
radio2         ds.b     1
radio3         ds.b     1
radio4         ds.b     1
radio5         ds.b     1

               segment 'ram1'

;-- PROGRAM ---------------------------------------------------
               segment 'rom'

;-- inicializace SETUP ----------------------------------------

main           sim
               mov   CLK_CKDIVR, #$18	   ;cpu rychlost               
               ldw   X, #stack_end
               ldw   SP, X
               ldw   X, #ram0_start
clear_ram0     clr   (X)
               incw  X
               cpw   X, #ram0_end	
               jrule clear_ram0
               ldw   X, #ram1_start
clear_ram1     clr  (X)
               incw  X
               cpw   X, #ram1_end	
               jrule clear_ram1	            
               ldw   X, #stack_start
clear_stack    clr  (X)
               incw  X
               cpw   X, #stack_end	
               jrule clear_stack               
i2c_init       bres  I2C_CR1, #0     ;PE=0
               clr   I2C_CR1         ;init i2c
               mov   I2C_FREQR, #16
               mov   I2C_CCRL, #80   ;CCR = 80 � 100 kHz
               clr   I2C_CCRH
               mov   I2C_TRISER, #17 ;TRISE = 16+1
               bset  I2C_CR1, #0     ;PE=1
               bres  PA_DDR, #PIN_INFRA   ;ifra input
               bset  PA_CR1, #PIN_INFRA   ;pull-up
               bres  EXTI_CR1, #0         ;rising ne
               bset  EXTI_CR1, #1         ;falling ano
               
tea5767_init   ldw   y, $4001
               ld    a, yh
               tnz   a
               jreq _initfq
               cp    a, #$FF
               jreq _initfq
               jra  _pokracuj      
_initfq        ldw   y, #DOLNI       ;87 MHz dolni okraj pasma
               call _uloz 
_pokracuj      call  tea5767w
               rim
                              
;-- hlavni smycka LOOP ----------------------------------------
          
infinite_loop
               call   tea5767r
               bset   PA_CR2, #PIN_INFRA
_cekej_infra   btjf   priznaky, #INFRA, _cekej_infra
               bres   priznaky, #INFRA
               ld     a, infra_kod
               cp     a, infra_ok
               jreq  _zapni
               cp     a, infra_hash
               jreq  _vypni
               cp     a, infra_up
               jreq  _vpredn
               cp     a, infra_right
               jreq  _vpred1
               cp     a, infra_down
               jreq  _zpetn
               cp     a, infra_left
               jreq  _zpet1
               cp     a, infra_hvez
               jreq  _uloz
               ldw   y, $4001
               callr  tea5767w               
               jra    infinite_loop
                                             
_vypni         ld     a, yh
               or     a, #$80
               ld     yh, a
               callr  tea5767w
               jra    infinite_loop

_zapni         ld     a, yh
               and    a, #$7F
               ld     yh, a
               callr  tea5767w
               jra    infinite_loop

_vpredn        addw   y, #11
_vpred1        incw   y
               cpw    y, #HORNI
               jrult _preskok1
               ldw    y, #DOLNI
_preskok1      callr  tea5767w
               jra    infinite_loop

_zpetn         subw   y, #11
_zpet1         decw   y
               cpw    y, #DOLNI
               jrugt  _preskok2
               ldw    y, #HORNI
_preskok2      callr  tea5767w
               jra    infinite_loop
               
_uloz          callr  uloz 
               jra    infinite_loop
               
uloz           ldw    x, #$4001
               pushw  y
               ld     a, yh
               and    a, #$7F
               ld     yh, a
               call   eeprom_zapisw
               popw   y
               ret
                              
;--- TEA-5767  -------------------------------------------------

tea5767w      ;zapise pres i2c - 5 bajtu do TEA5767 v Y je ladeni
               bset   I2C_CR2, #0
_startw        btjf   I2C_SR1, #0, _startw   ;start spusten
               ld     a, #TEA5767_ADR        ;0x60 
               sll    a                      ;adresa pro zapis
               ld     I2C_DR, a 
_waitaddrw     btjf   I2C_SR1, #1, _waitaddrw  ;cekat na ADDR               
               ld     a, I2C_SR3             ;dummy read kvuli clear ADDR   
               ld     a, yh                  ;1.byte ladeni 1
               ld     I2C_DR, a              
_wtx1          btjf   I2C_SR1, #7, _wtx1     
               ld     a, yl                  ;2.byte ladeni 2
               ld     I2C_DR, a
_wtx2          btjf   I2C_SR1, #7, _wtx2
               mov    I2C_DR, #$08           ;3.byte 0x08=mono / 0=stereo
_wtx3          btjf   I2C_SR1, #7, _wtx3
               mov    I2C_DR, #$10           ;4.byte xtal
_wtx4          btjf   I2C_SR1, #7, _wtx4
               clr    I2C_DR                 ;5.byte default
_wtx5          btjf   I2C_SR1, #7, _wtx5
               bset   I2C_CR2, #1            ;i2c stop transakce
               ret

tea5767r      ;precte pres i2c - 5 bajtu 
               bset   I2C_CR2, #0
_startr        btjf   I2C_SR1, #0, _startr   ;start spusten
               ld     a, #TEA5767_ADR        ;0x60 
               sll    a
               or     a, #1                  ;adresa pro cteni
               ld     I2C_DR, a 
_waitaddrr     btjf   I2C_SR1, #1, _waitaddrr ;cekat na ADDR               
               ld     a, I2C_SR3              ;dummy read kvuli clear ADDR   
               bset   I2C_CR2, #2             ;ACK=1               
_wb1           btjf   I2C_SR1, #6, _wb1       ;cte 1.byte
               mov    radio1, I2C_DR
_wb2           btjf   I2C_SR1, #6, _wb2       ;cte 2.byte
               mov    radio2, I2C_DR
_wb3           btjf   I2C_SR1, #6, _wb3       ;cte 3.byte
               mov    radio3, I2C_DR
_wb4           btjf   I2C_SR1, #6, _wb4       ;cte 4.byte
               mov    radio4, I2C_DR
               bres   I2C_CR2, #2             ;nasleduje posledni bajt, ACK=0 (NACK)
               bset   I2C_CR2, #1             ;STOP=1
_wb5           btjf   I2C_SR1, #6, _wb5
               mov    radio5, I2C_DR          ;cte 5.byte               
               ret
               
;--- infra -----------------------------------------------------
 
mereni_l      ;zmeri pocet taktu LOW 6 + (y * 6)
               clrw    y  
_r1            incw    y  
               jrv     _e1                 ; pokud pretece, ven
               btjf    PA_IDR, #PIN_INFRA, _r1
_e1            ret

mereni_h      ;zmeri pocet taktu HIGH 6 + (y * 6)
               clrw    y
_r2            incw    y
               jrv     _e2                ; pokud pretece, ven
               btjt    PA_IDR, #PIN_INFRA, _r2
_e2            ret
               
read_raw      ;meri delky impulzu
               ldw     x, #raw_infra
               mov     raw_cnt, #32
               callr   mereni_l   ; cekej na high
               jrv    _e3         ; pokud pretekl, tak ven 
repe           callr   mereni_h   ; zmer delku high
               jrv    _e3         ; pokud pretekl, tak ven 
               ld      a, yh      ; postaci ulozit pouze vyssi byte
               ld     (x), a
               incw    x
               callr   mereni_l   ; cekej na dalsi high
               dec     raw_cnt
               jrne    repe
_e3            ret

kod_infra     ;bypocte byte z raw dat X=cil, Y=raw
               clr   (x)
               ld     a, (y)          ;1. bit
               cp     a, #HRANICE_0_1 
               jrult  nula
               ld     a, #1
               ld    (x), a
nula           incw   y
               mov    raw_cnt, #7     ;dalsich 7 bitu
dalsi_bit      sll   (x)
               ld     a, (y)          ;1. bit
               cp     a, #HRANICE_0_1 
               jrult  nula2
               ld     a, (x)
               or     a, #1
               ld    (x), a               
nula2          incw   y
               dec    raw_cnt
               jrne   dalsi_bit
               ret
               
nec_test      ;otestovat platnost prijateho kodu podle NEC
               bres   priznaky, #NEC_VALID ;init na neplatny
               ldw    x, #infra_long
               ld     a, (x)
               xor    a, (1,x)
               cp     a, #$ff
               jrne  _ne
               ld     a, (2,x)
               xor    a, (3,x)
               cp     a, #$ff
               jrne  _ne               
               bset   priznaky, #NEC_VALID ;nec platny
_ne            ret

;-- EEPROM ----------------------------------------------------

eeprom_zapisw ;zapise obsah Y na adresu X
               push   a
               ld     a, yh
               callr  eeprom_zapis8
               incw   x
               ld     a, yl
               callr  eeprom_zapis8
               pop    a
               ret
               
eeprom_zapis8 ;zapise A na adresu X
               mov    FLASH_DUKR, #$ae         ;1. byte pro odemceni  
               mov    FLASH_DUKR, #$56         ;2. byte pro odenceni
_cekej_zap     btjt   FLASH_IAPSR, #0, _cekej_zap ;cekej, na povoleni zapisu
               ld    (x), a
_cekej_konec   btjt   FLASH_IAPSR, #0, _cekej_konec ;cekej dokonceni zapisu
               bres   FLASH_IAPSR, #3          ;nakonec zamkni eeprom
               ret
               
;---IRQ -------------------------------------------------------
               interrupt infra_interrupt
infra_interrupt.l
               bres   PA_CR2, #PIN_INFRA       ;zakaz preruseni 
               btjt   PA_IDR, #PIN_INFRA, _nic ;pokud tu neni nula, tak ven
               call   mereni_l            
               jrv   _nic              ;pokud pretekl, tak ven 
               cpw    y, #INFRA_START  ;je start?
               jrult _nic              ;  ne, ven
               call   mereni_h         ;  ano
               jrv   _nic              ;pokud pretekl, tak ven 
               call   read_raw         ;mereni delek impulzu  
               jrv    _nic             ;pokud pretekl, tak ven 
               ldw    y, #raw_infra    ;preved delky impuzu na bity
               ldw    x, #infra_long
               call   kod_infra        ;1.byte
               incw   x
               call   kod_infra        ;2.byte
               incw   x
               call   kod_infra        ;3.byte
               incw   x
               call   kod_infra        ;4.byte
               call   nec_test
               btjf   priznaky, #NEC_VALID, _nic  ;nec test nevysel
               bset   priznaky, #INFRA  ;priznak kod precten pro hlavni smycku
               jra   _iret              ;preruseni se povoli v hlavni smycce
_nic           bset   PA_CR2, #PIN_INFRA     ;povol preruseni
_iret          iret

               interrupt NonHandledInterrupt
NonHandledInterrupt.l
               iret

;-- konstanty -------------------------------------------------

infra_0        dc.b      $67 ; kody ovladace
infra_1        dc.b      $5d  
infra_2        dc.b      $9d
infra_3        dc.b      $1d
infra_4        dc.b      $dd
infra_5        dc.b      $fd
infra_6        dc.b      $3d
infra_7        dc.b      $1f
infra_8        dc.b      $57
infra_9        dc.b      $6f
infra_hvez     dc.b      $97
infra_hash     dc.b      $4f
infra_hash2    dc.b      $79 ; ?
infra_up       dc.b      $e7
infra_down     dc.b      $b5
infra_left     dc.b      $ef
infra_right    dc.b      $a5
infra_ok       dc.b      $c7
verze          dc.b      "TEA6757 + infra, ver. 1.0 release 001"

;--------------------------------------------------------------
	             segment 'vectit'

               dc.l {$82000000+main                 ; reset
               dc.l {$82000000+NonHandledInterrupt} ; trap
               dc.l {$82000000+NonHandledInterrupt} ; TLI_IRQHandler; External Top Level interrupt
               dc.l {$82000000+NonHandledInterrupt} ; Auto Wake Up from Halt
               dc.l {$82000000+NonHandledInterrupt} ; Clock Controller
               dc.l {$82000000+infra_interrupt}     ; EXTI Port A
               dc.l {$82000000+NonHandledInterrupt} ; EXTI Port B
               dc.l {$82000000+NonHandledInterrupt} ; EXTI Port C
               dc.l {$82000000+NonHandledInterrupt} ; EXTI Port D
               dc.l {$82000000+NonHandledInterrupt} ; EXTI Port E
               dc.l {$82000000+NonHandledInterrupt} ; CAN Rx (STM8AF only, N/A on STM8S103)
               dc.l {$82000000+NonHandledInterrupt} ; CAN Tx (STM8AF only, N/A on STM8S103)
               dc.l {$82000000+NonHandledInterrupt} ; SPI
               dc.l {$82000000+NonHandledInterrupt} ; TIM1 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt} ; TIM1 Capture/Compare
               dc.l {$82000000+NonHandledInterrupt} ; TIM2 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt} ; TIM2 Capture/Compare
               dc.l {$82000000+NonHandledInterrupt} ; TIM3 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt} ; TIM3 Capture/Compare
               dc.l {$82000000+NonHandledInterrupt} ; UART1 Tx complete
               dc.l {$82000000+NonHandledInterrupt} ; UART1 Rx full
               dc.l {$82000000+NonHandledInterrupt} ; I2C
               dc.l {$82000000+NonHandledInterrupt} ; UART2 (not present on STM8S103)
               dc.l {$82000000+NonHandledInterrupt} ; UART2 (not present on STM8S103)
               dc.l {$82000000+NonHandledInterrupt} ; ADC1 end of conversion
               dc.l {$82000000+NonHandledInterrupt} ; TIM4 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt} ; EEPROM EEC
               dc.l {$82000000+NonHandledInterrupt} ; irq25
               dc.l {$82000000+NonHandledInterrupt} ; irq26
               dc.l {$82000000+NonHandledInterrupt} ; irq27
               dc.l {$82000000+NonHandledInterrupt} ; irq28
               dc.l {$82000000+NonHandledInterrupt} ; irq29

               end

všeobecné informace

U modulů, které jsem v rámci svých možností odladil a otestoval, jsem vytvořil prográmek, který lze formou copy-paste vytáhnout (buď celý, nebo pouze potřebné kusy kódu) a použít jej v nějaké Vaší aplikaci. Zkopírovat se musí potřebný kód, proměnné v paměti a deklarace konstant (equ).

Na stránkách výrobce ST Microelectronics je ke stažení vývojové prostředí ST Visual develop a dále jsou zde velmí podrobné manuály v PDF (v angličtině) odledně popisu mikrokontroléru a jeho instrukčního souboru.

Každý zde uváděný zdroják má stejnou strukturu. Na začátku jsou deklarace adres použitých systémových registrů (UART, I2C, GPIO...), což je klíčové. Tyto adresy jsou popsány jednak v datasheetu STM8, a také jsou k dispozici ve zdrojovém kódu, který je nainstalován spolu s prostředím ST Visual develop ve složce [Program Files]\ STMicroelectronics\ st_toolset\ asm\ include\ STM8S103F.asm). Asi je možné ji deklarovat jako include, ale zde jsou ve zdrojáku definovány pouze ty, které jsou použity.
Dále je inicializační část, kde je vynulována paměť ram, nastaví se rychost CPU a proběhne základní nastavení použitého hardware, například rychlost UARTu, GPIO input/output, atd. Pak už následují rutiny pro konkrétní modul.V nekonečné smyčce infinite_loop je ukázka činnosti. Samotné rutiny lze podle potřeby vykopírovat do jiného projektu. Úplně na konci je tabulka vektorů přerušení v segmentu vectit s popisy, které zařízení může přerušení vyvolat.

Rychlý návod jak vytvořit nový projekt v prostředí ST Visual Dvelop:

V Hlavním menu vybrat File a New workspace.
Zvolit položku Create workspace and project
Objeví se dialog pro zadání skupiny projektů.
Vyplňte pole workspace filename (název skupiny projektů)
Vyyplňte pole workspace location (složka pro umístění)
Naskočí další okno pro projekt.
Vyplňte pole project filename (název projektu)
Vyplňte pole project location (složka pro umístěni projektu, zde doporučuji vybrat podsložku skupiny projektů).
Do pole toolchain vyberte ST Assembler Linker.
Pole toolchain root ponechte nezměněno.
Naběhne výběr pro konkrétní CPU.
Vyberte v něm STM8S103F3P.

Tím se vytvoří projekt. Na levé straně se objeví strom Workspace, kde ve větvi source files otevřete main.asm, které je hlavní zdroják projektu. Je předvyplněn o počáteční definici segmentů a tabulku přerušení. Můžete jej vyčistit a pak do něj přes copy-paste (CTRL+A - CTRL+C -> CTRL+V) vložit některé s zde uváděných mých (nebo Vašich) zdrojáků. Soubory mapping.asm a mapping.inc systém vytvořil automaticky a není doporučeno do nich zasahovat, protože systém je interně přepisuje. Do téhož workspace můžete vkládat více projektů, každý však musí mít svou složku.
Do existujícího workspace pak lze přidávat libovolný počet projektů, pomocí pravého tlačítka myši na kořenové (nejvyšší) větvi stromu "workspace". Podmínkou je, aby každý projekt byl v samostatné složce (adresáři). Do podvětví source files, nebo include files, každého projektu se mohou přidávat další moduly. Další podrobnosti ohledně práce v prostředí ST Visual develop je v tomto manuálu (anglicky).

Nahrání (vypálení) programu do modulu:

RTC Především připojte k modulu vývojové desky STM8S103F3 programátor ST-Link. K tomu jsou určeny čtyři piny na desce vpravo: 3V3, SWIM, GND a NRST (viz obrázek vlevo).
Program lze vypálit přímo z prostředí "ST Visual Dvelopu" takto: v hlavním menu vyberte Build - Build (F7). Pokud překlad a sestavení proběhhne bez chyb, spusťte Debug - Start debugging. Tím se projekt nahraje (vypálí), naskočí okno debuggeru a případně můžete projekt spustit (F5), nebo krokovat (F10).
Vypálit program do STM8 se dá i jednodušeji pomocí ST Visual Programmer, pokud máte k dispozici již "visual developem" přeložený soubor (F7-build, viz výše) *.s19. Tento vznikne v podsložce projektu DEBUG, nebo RELEASE. Otevřete jej přes hlavní menu-File-Open a přes hlavní menu-Program-Current tab program vypálíte. Případně ještě můžete správnost vypálení ověřit pomocí hlavní menu-Verify-Current tab. Další podobnosti odhledně používání ST Visual Programmeru jsou v jeho nápovědě: hlavní menu-Help-Index.

Dúležité upozornění: Zde presentovaný modul mikrokontroléru má výstupy 5V, 3V3 a GND. Na výstupu 5V ve skutečnosti není 5 voltů, ale vstupní napětí, kterým celý tento modul napájíte, buď přes piny +/-, nebo přes konektor mikroUSB, což může být 4.5 - 15V. Buďte opatrní, co k tomu pinu (5V) připojíte, připojovaný modul můžete tímto zničit. Doporučuji modul napájet výhradně z 5V zdroje.

Elektronika, ukázky pro Arduino a STM8, plus programování v Delphi (Lazarusu).

Všechna zapojení modulů v ukázkách (viz elektrická schémata) pracují s velmi malým napětím 3.3V až 12V a neobsahují návod na napájecí zdroj. Pokud se rozhodnete některé z těchto zařízení postavit, důrazně doporučuji používat zdroje s výstupním napětím maximálně 12V, podle schválených norem platných v ČR. Autor návodů za případné škody nepřebírá žádnou odpovědnost.

nahoru