Elektronika, ukázky pro STM8S103F3, plus programování v assembleru.

Jednoduchý MP3 přehrávač v2

pomocí MP3 modulu DFPlayer mini

Tento přehrávač s modulem DF Player mini Datasheet modulu DFPlayer mini, ze kterého jsem čerpal na internetu, již jaksi nemohu najít. Dávam zde tedy odkaz ke stažení z mých zdrojů, snad se výrobce nebude zlobit. Přehrávač je velmi podobný předtím publikovanému přehrávačí pro Arduino. Rozdíl je hlavně v tom, že pro ovládání je místo tří tlačítek použito pět. Tlačítka pro play/pause, o jeden vpřed a o jeden zpět jsou připojena přímo k modulu DF Player mini (viz schéma), který toto umožňuje. Tím se trochu ušetří programování mikrokontroléru. Tlačítka u DF Player mini vpřed/zpět zároveň regulují i hlasitost při jejich dlouhém stisku. Takovéto ovládání hlasitosti je trochu neohrabané, zde je pro hlasitost rotační enkodér. Dlouhý stisk tlačítek lze samozřejmě používat takě.
Mikrokontrolér (STM8) řídí tlačítka o deset vpřed/zpět a rotační enkodér pro hlasitost a equalizer (stiskem knoflíku). Dále reaguje na události na sériové lince (UART) a čte stav pinu BUSY modulu DF Player mini.

Modul posílá info na UART při vložení a vyjmutí paměťové karty a také při připojení a odpojení kabelu USB. Trochu je problém se zjišťováním pořadí právě přehrávaného souboru. Modul sice pošle info při ukončení skladby, ale pokud posunete tlačítkem o jedno vpřed, nebo zpět, nepošle nic. Tato informace je však potřebná pro uložení do EEPROM. V programu se to řeší tak, že každých asi pět vteřin se pošle dotaz na pořadí (příkaz 0x4C, viz datasheet ke stažení níže). Do EEPROM se uloží, pouze pokud se pořadí změnilo. Naprogramováno je to samozřejmě v assembleru.
Modul ja napájen napětím 5 V, odběr do sluchátek je asi 20 mA. Napájet jej lze z konektoru mikro USB, který je na desce mikrokontroléru, nebo z pinů plus a mínus tamtéž. Tyto jsou i vhodné pro napájení z baterií. Další možnost napájení je i z USB konektoru, který je možno připojit z modulu DF Player mini. Pomocí něj lze i nahrávat paměťovou kartu, pokud jej připojíte k počítači. Dopručuji, abyste z těchto možností použili vždy pouze jednu, aby nebyly připojeny dva zdroje napájení současně (např. baterie a USB). Pro uspěšný překlad je nutný malý modul níže, pro ukládání bajtů a 16-bit slov do EEPROM mikrokontroléru. Modul lze použít obecně, do jakýchkoliv jiných projektů. Zde se ukládá pouze pořadí aktuální skladby, aby po opětovném zapnutí se nezačínalo vždy od začátku.
Pomocí programu ST Visual programmer lze do modulu STM8 vypálit již přeložený a sestavený kód, který si můžete stáhnout zde.

stm8/

              .form 64
              .tab 10,8,18,60
               TITLE "STM8"
               
               extern eeprom_zapis16, eeprom_cteni16

              #include "mapping.inc"

ram0_start.b   equ  $ram0_segment_start
ram0_end.b     equ  $ram0_segment_end
ram1_start.w   equ  $ram1_segment_start
ram1_end.w     equ  $ram1_segment_end	
stack_start.w  equ  $stack_segment_start 
stack_end.w    equ  $stack_segment_end

;-------------------------------------------------------------------------------

CLK_CKDIVR     equ  $50C6 ;CPU delicka pro rychlost
EXTI_CR1       equ  $50A0 ;IRQ typ
EXTI_CR2       equ  $50A1 

UART_SR        equ  $5230  ;UART1
UART_DR        equ  $5231
UART_BRR1      equ  $5232
UART_BRR2      equ  $5233
UART_CR1       equ  $5234
UART_CR2       equ  $5235

PA_IDR         equ  $5001 ;port A pro busy DF
PIN_BUSY       equ  3
PC_ODR         equ  $500A ;port C
PC_IDR         equ  $500B
PC_DDR         equ  $500C
PC_CR1         equ  $500D
PC_CR2         equ  $500E
ROT_SW         equ  3
CLK_TEST       equ  $20   ;pin C5=CLK, C4=DT
TT4            equ  7     ;tlacitlp T4 - priznaky 
TT5            equ  6     ;tlacitko T5
SW             equ  3     ;rot. tlacitko

IRQ_MASKA      equ  $c8   ;1100 1000
NEG_MASKA      equ  $37   ;0011 0111
UART_RX        equ  5     ;paket byl prijat
AE_PORADI      equ  2     ;adresa eeprom poradi

;-- RAM0 promenne---------------------------------------------------------------
               segment 'ram0'
               
prijaty        ds.b     1   ;uart DFplayer paketa
               ds.b     2   ;7E FF 
odeslat        ds.b     1   ;6
prikaz         ds.b     1   ;prikaz
feedback       ds.b     1
hi_param       ds.b     1
lo_param       ds.b     1
               ds.b     2   ;kontrolni soucet chs1, chs2
               ds.b     1   ;EF konec pakety

;-- RAM1 promenne---------------------------------------------------------------
               segment 'ram1'

priznaky       ds.b     1
index_hi       ds.b     1
index_lo       ds.b     1
ton            ds.b     1
rotakt         ds.b     1
rotpred        ds.b     1
rotpot         ds.b     1   ;rotacni potenciometr hodnota
pocet          ds.w     1   ;pocet MP3
pocitadlo      ds.l     1

;-- PROGRAM --------------------------------------------------------------------
               segment 'rom'

;-- inicializace SETUP ---------------------------------------------------------

main           sim
               ldw   X, #stack_end
               ldw   SP, X
               ldw   X, #ram0_start
clear_ram0     clr   (X)
               incw  X
               cpw   X, #ram0_end	
               jrule clear_ram0
               ldw   X, #ram1_start
clear_ram1     clr  (X)
               incw  X
               cpw   X, #ram1_end	
               jrule clear_ram1	            
               ldw   X, #stack_start
clear_stack    clr  (X)
               incw  X
               cpw   X, #stack_end	
               jrule clear_stack
               mov   CLK_CKDIVR, #$18   ;cpu rychlost             

;------------------------------------------------------------------------------

               mov    EXTI_CR1, #$20     ;port C irq falling   
               clr    PC_DDR             ;cely PC na input
               bset   PC_CR1, #ROT_SW    ;input pool-up               
               mov    UART_BRR2, #$00    ;UART 9600 bd, pri 2MHz CPU
               mov    UART_BRR1, #$0d
               bset   UART_CR2,#3        ;povoli TX
               bset   UART_CR2,#2        ;povoli RX               
               mov    rotpot, #18
               call   cekej_sec
               rim
               clrw   y
               bset   UART_CR2,#5        ;povoli preruseni RX
               ld     a, #$0c            ;reset DF
               call   txc                ;otestovat/cekat vlozeni
busy           btjf   PA_IDR, #PIN_BUSY, busy
               call   cekej_sec
               clrw   y
               ld     a, #$48            ;pocet skladeb
               call   txc
               mov    pocet, hi_param    ;ulozi pocet skladeb
               mov   {pocet+1}, lo_param               
               call   cekej_sec
               ldw    x, #AE_PORADI
               call   eeprom_cteni16
               cpw    x, pocet           ;pokud je pocet nizsi, nez aktualni
               jrsgt  play1              ; nebude nacitat ulozene poradi
               ldw    y, x
               ld     a, #3
               call   tx2
play1          btjt   PA_IDR, #PIN_BUSY, play1 ;cekej na play
               
;-- hlavni smycka LOOP ---------------------------------------------------------

infinite_loop  mov    PC_CR2, #IRQ_MASKA ;povoli preruseni tlacitek T4, T5, SW
               call   inc32               
               ld     a, {pocitadlo+1}
               cp     a, #3
               jrult  pokracuj
               call   pocreset
               btjt   PA_IDR, #PIN_BUSY, pokracuj ;pokud nehraje, tak neukladej
               ld     a, #$4c
               call   tx
pokracuj       ldw    x, #AE_PORADI               ;zjisti aktualni ulozenou 
               call   eeprom_cteni16
               ldw    y, x
               btjt   priznaky, #TT4, vpred10
               btjt   priznaky, #TT5, zpet10
               btjt   priznaky, #SW, ton_clona
               btjt   priznaky, #UART_RX, rx
               call   rotace
               jrc    hlasitost
               jra    infinite_loop

hlasitost      ld     a, rotpot
               call   tx
               jra    infinite_loop               
zpet10         bres   priznaky, #TT5
               subw   y, #10                   ;odecte 10
               jrnc   preskok
               ldw    y, #1
               jra    preskok
vpred10        bres   priznaky, #TT4
               addw   y, #10                   ;pricte 10
               cpw    y, pocet
               jrsle  preskok
               ldw    y, pocet
preskok        ldw    x, #AE_PORADI
               call   eeprom_zapis16
               ld     a, #3               
               call   tx2
play2          btjt   PA_IDR, #PIN_BUSY, play2 ;cekej na play
               jra    infinite_loop
               
ton_clona      bres   priznaky, #SW
               clrw   y
               ld     a, ton
               inc    a
               cp     a, #5
               jrule _ton1
               clr    a
_ton1          ld     ton, a
               ld     yl, a
               ld     a, #7
               call   tx2
               jp     infinite_loop
               
;-- RX ------------------------------------------------------------------------

rx             bres   priznaky, #UART_RX  ;prijem
               ld     a, prikaz
               cp     a, #$3d             ;skladba skoncila
               jreq   dalsi
               cp     a, #$4c             ;aktualni skladba               
               jreq   uloz_aktualni
               cp     a, #$3a             ;USB pripojeno
               jreq   usb_pripojeno
               cp     a, #$3b             ;karta vyjmuta/USB odpojeno, restart
               jrne   navrat
               jp     main
dalsi          ld     a, #1               ;dalsi skladba
               callr  tx
               jra    navrat               
uloz_aktualni  ldw    x, #AE_PORADI       ;aktualni skladba
               call   eeprom_cteni16
               cpw    x, hi_param               
               jreq   navrat
               ldw    x, #AE_PORADI
               ldw    y, hi_param
               call   eeprom_zapis16
navrat         jp     infinite_loop

usb_pripojeno  btjt   priznaky, #UART_RX, usb_pripojeno
               ld     a, prikaz           ;po odpojeni USB, opetovne spusteni
               cp     a, #$3b
               jrne   usb_pripojeno
               jp     main

;-- TX ------------------------------------------------------------------------

tx             clrw   y                   ;pro volani bez parametru
tx2            btjf   UART_SR, #7, tx     ;cekat na prazdny TX
               push   a                   ;A=prikaz, YL=loparam, YH=hiparam
               ld     a, #$7E
               callr  byte_tx             ;7E
               ld     a, #$FF
               callr  byte_tx             ;FF
               ld     a, #6
               callr  byte_tx             ;6
               pop    a                   ;prikaz
               callr  byte_tx
               clr    a                   ;feedback
               callr  byte_tx
               ld     a, yh               ;hi param
               callr  byte_tx
               ld     a, yl               ;lo param
               callr  byte_tx
               ld     a, #$EF
               callr  byte_tx
_tx08          btjf   UART_SR, #6, _tx08
               ret
               
txc            callr  tx2                ;A=prikaz, YL=loparam, YH=hiparam
cekej_rx       btjf   priznaky, #UART_RX, cekej_rx
               bres   priznaky, #UART_RX  ;shod priznak
               ret
               
byte_tx        ld     UART_DR, a          ;odesli byte
_txc           btjf   UART_SR, #7, _txc
               callr  pauza               ;mala prodleva mezi bytes
               ret

;-------------------------------------------------------------------------------
               
rotace        ;zjisteni stavu rot +/- rotpot, carry pri zmene
               ld     a, PC_IDR          ;precte GPIO CLK, test zmeny
               and    a, #CLK_TEST
               ld     rotakt, a
               cp     a, rotpred         ;byla zmena?
               jrne  _zmena              ;  ne, shod carry a ven
_nic           rcf
               ret
_zmena         callr  pauza              ;byla zmena
               ld     a, PC_IDR          ;precte GPIO DT
               sll    a
               and    a, #CLK_TEST       ;zjisti smer otoceni
               cp     a, rotakt
               jrne  _vpravo
               mov    rotpot, #5         ;uber
               jra   _rotven
_vpravo        mov    rotpot, #4         ;pridej
_rotven        callr  pauza              ;pauza
               ld     a, PC_IDR
               and    a, #CLK_TEST       ;uloz stav
               ld     rotpred, a
               scf                       ;nahod carry, priznak zmeny 
               ret

pauza          push   #32
_pauza1        nop
               dec   (1,SP)
               jrne  _pauza1
               addw   SP, #1
               ret
               
cekej_sec      callr  pocreset
_cekej1        callr  inc32
               ld     a, {pocitadlo+1}
               tnz    a
               jreq  _cekej1
               callr  pocreset
               ret
                           
inc32          ldw    x, #pocitadlo
               ld     a, (3,x)      ;pricte +1 k 32-bit hodnote
               add    a, #1
               ld    (3,x), a               
               ld     a, (2,x)
               adc    a, #0
               ld    (2,x), a               
               ld     a, (1,x)
               adc    a, #0
               ld    (1,x), a               
               ld     a, (x)
               adc    a, #0
               ld    (x), a
               ret
               
pocreset       clr    pocitadlo
               clr    {pocitadlo+1}
               clr    {pocitadlo+2}
               clr    {pocitadlo+3}
               ret
               
;---IRQ ------------------------------------------------------------------------

               interrupt rx_irq              ;UART
rx_irq.l       mov    prijaty, UART_DR
_precten       btjt   UART_SR, #5, _precten  ;cekej dokud nezmizi
               ld     a, prijaty
               cp     a, #$7E                ;pocatek pakety?
               jrne  _dbyte                  ; ne
               clr    index_hi               ; ano, vynuluj index
               clr    index_lo               
_dbyte         inc    index_lo               ;zvys index o 1
               ldw    x, index_hi
               ld    (x), a                  ;uloz byte
               cp     a, #$FE                ;konec pakety?
               jrne  _ret                    ; ne
               bset   priznaky, #UART_RX     ; ano, nahod priznak
_ret           iret

               interrupt tc_irq              ;tacitka T4, T5 a SW
tc_irq.l       clr    PC_CR2                 ;zakaze preruseni
               ld     a, priznaky
               and    a, #NEG_MASKA          ;shodi priznaky
               ld     priznaky, a
               ld     a, PC_IDR
               cpl    a
               and    a, #IRQ_MASKA
               or     a, priznaky
               ld     priznaky, a
_tc3           iret
               
               interrupt NonHandledInterrupt
NonHandledInterrupt.l
               iret

;-- konstanty ------------------------------------------------------------------


;-------------------------------------------------------------------------------
	             segment 'vectit'

               dc.l {$82000000+main                 ; reset
               dc.l {$82000000+NonHandledInterrupt} ; trap
               dc.l {$82000000+NonHandledInterrupt} ; TLI_IRQHandler; External Top Level interrupt
               dc.l {$82000000+NonHandledInterrupt} ; Auto Wake Up from Halt
               dc.l {$82000000+NonHandledInterrupt} ; Clock Controller
               dc.l {$82000000+NonHandledInterrupt} ; EXTI Port A
               dc.l {$82000000+NonHandledInterrupt} ; EXTI Port B
               dc.l {$82000000+tc_irq}              ; EXTI Port C
               dc.l {$82000000+NonHandledInterrupt} ; EXTI Port D
               dc.l {$82000000+NonHandledInterrupt} ; EXTI Port E
               dc.l {$82000000+NonHandledInterrupt} ; CAN Rx (STM8AF only, N/A on STM8S103)
               dc.l {$82000000+NonHandledInterrupt} ; CAN Tx (STM8AF only, N/A on STM8S103)
               dc.l {$82000000+NonHandledInterrupt} ; SPI
               dc.l {$82000000+NonHandledInterrupt} ; TIM1 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt} ; TIM1 Capture/Compare
               dc.l {$82000000+NonHandledInterrupt} ; TIM2 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt} ; TIM2 Capture/Compare
               dc.l {$82000000+NonHandledInterrupt} ; TIM3 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt} ; TIM3 Capture/Compare
               dc.l {$82000000+NonHandledInterrupt} ; UART1 Tx complete
               dc.l {$82000000+rx_irq}              ; UART1 Rx full
               dc.l {$82000000+NonHandledInterrupt} ; I2C
               dc.l {$82000000+NonHandledInterrupt} ; UART2 (not present on STM8S103)
               dc.l {$82000000+NonHandledInterrupt} ; UART2 (not present on STM8S103)
               dc.l {$82000000+NonHandledInterrupt} ; ADC1 end of conversion
               dc.l {$82000000+NonHandledInterrupt} ; TIM4 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt} ; EEPROM EEC
               dc.l {$82000000+NonHandledInterrupt} ; irq25
               dc.l {$82000000+NonHandledInterrupt} ; irq26
               dc.l {$82000000+NonHandledInterrupt} ; irq27
               dc.l {$82000000+NonHandledInterrupt} ; irq28
               dc.l {$82000000+NonHandledInterrupt} ; irq29

               end

Ukládání dat do EEPROM

EEPROM je v mikrokontroléru STM8S103F3 umístěná na adresách 0x4000 až 0x427F, celkem 640 byte. Tento modul umožňuje ukládání bajtu (byte), nebo slova (word). Ukládaný byte se vloží do akumulátoru (ld A, [hodnota]), pokud se ukládá slovo (word), vloží se do registru Y (ldw Y, [hodnota]). Adresa na kterou se má hodnota uložit je v registru X. Adresa se zádává v rozsahu 0 - 639. V modulu se k ní přičte 0x4000. Nakonec se zavolá eeprom_zapis8, respektive eeprom_zapis16. V modulu jsou implementovány i instrukce pro čtení. Jde o prosté přečtení bajtu, nebo slova z adresy. Byte se přečte do akumulátoru (eeprom_cteni8) a slovo (eeprom_cteni16) se přečte do registru X. Adresa, odkud se má číst je v obou případech v registru X. Opět se zadává v rozsahu 0 až 639. Bližší info, viz poznámky ve zdrojáku.

stm8/

;-------------------------------------------------------------------------------
;
;             modul pro zapis byte do eeprom
;             adresa se zadava v rozsahu 0x0000 - 0x027F (0 - 639)
;            
;-------------------------------------------------------------------------------

               public eeprom_zapis8, eeprom_cteni8, eeprom_zapis16, eeprom_cteni16

FLASH_DUKR     equ  $5064  
FLASH_IAPSR    equ  $505F

;-------------------------------------------------------------------------------
               segment 'rom'

;-- zapise A na adresu X+0x4000  -----------------------------------------------

eeprom_zapis8  mov    FLASH_DUKR, #$ae              ;1. byte pro odemceni  
               mov    FLASH_DUKR, #$56              ;2. byte pro odenceni
_cekej_zap     btjt   FLASH_IAPSR, #0, _cekej_zap   ;cekej, na povoleni zapisu
               ld    ($4000,x), a
_cekej_konec   btjt   FLASH_IAPSR, #0, _cekej_konec ;cekej dokonceni zapisu
               bres   FLASH_IAPSR, #3               ;nakonec zamkni eeprom
               ret
               
eeprom_cteni8  ld     a, ($4000,x)                  ;precte do A z adresy X
               ret

;-- zapise Y na adresu X+0x4000  -----------------------------------------------

eeprom_zapis16 push   a
               mov    FLASH_DUKR, #$ae              ;1. byte pro odemceni  
               mov    FLASH_DUKR, #$56              ;2. byte pro odenceni
_cekej_z       btjt   FLASH_IAPSR, #0, _cekej_z     ;cekej, na povoleni zapisu
               ld     a, yh
               ld     ($4000,x), a
_cekej_1       btjt   FLASH_IAPSR, #0, _cekej_1     ;cekej dokonceni zapisu
               ld     a, yl
               ld     ($4001,x), a              
_cekej_2       btjt   FLASH_IAPSR, #0, _cekej_2     ;cekej dokonceni zapisu
               bres   FLASH_IAPSR, #3               ;nakonec zamkni eeprom
               pop    a
               ret
               
eeprom_cteni16 ldw    x, ($4000,x)                  ;precte do X z adresy X
               ret

;-------------------------------------------------------------------------------

               END

všeobecné informace

U modulů, které jsem v rámci svých možností odladil a otestoval, jsem vytvořil prográmek, který lze formou copy-paste vytáhnout (buď celý, nebo pouze potřebné kusy kódu) a použít jej v nějaké Vaší aplikaci. Zkopírovat se musí potřebný kód, proměnné v paměti a deklarace konstant (equ).

Na stránkách výrobce ST Microelectronics je ke stažení vývojové prostředí ST Visual develop a dále jsou zde velmí podrobné manuály v PDF (v angličtině) odledně popisu mikrokontroléru a jeho instrukčního souboru.

Každý zde uváděný zdroják má stejnou strukturu. Na začátku jsou deklarace adres použitých systémových registrů (UART, I2C, GPIO...), což je klíčové. Tyto adresy jsou popsány jednak v datasheetu STM8, a také jsou k dispozici ve zdrojovém kódu, který je nainstalován spolu s prostředím ST Visual develop ve složce [Program Files]\ STMicroelectronics\ st_toolset\ asm\ include\ STM8S103F.asm). Asi je možné ji deklarovat jako include, ale zde jsou ve zdrojáku definovány pouze ty, které jsou použity.
Dále je inicializační část, kde je vynulována paměť ram, nastaví se rychost CPU a proběhne základní nastavení použitého hardware, například rychlost UARTu, GPIO input/output, atd. Pak už následují rutiny pro konkrétní modul.V nekonečné smyčce infinite_loop je ukázka činnosti. Samotné rutiny lze podle potřeby vykopírovat do jiného projektu. Úplně na konci je tabulka vektorů přerušení v segmentu vectit s popisy, které zařízení může přerušení vyvolat.

Rychlý návod jak vytvořit nový projekt v prostředí ST Visual Dvelop:

V Hlavním menu vybrat File a New workspace.
Zvolit položku Create workspace and project
Objeví se dialog pro zadání skupiny projektů.
Vyplňte pole workspace filename (název skupiny projektů)
Vyyplňte pole workspace location (složka pro umístění)
Naskočí další okno pro projekt.
Vyplňte pole project filename (název projektu)
Vyplňte pole project location (složka pro umístěni projektu, zde doporučuji vybrat podsložku skupiny projektů).
Do pole toolchain vyberte ST Assembler Linker.
Pole toolchain root ponechte nezměněno.
Naběhne výběr pro konkrétní CPU.
Vyberte v něm STM8S103F3P.

Tím se vytvoří projekt. Na levé straně se objeví strom Workspace, kde ve větvi source files otevřete main.asm, které je hlavní zdroják projektu. Je předvyplněn o počáteční definici segmentů a tabulku přerušení. Můžete jej vyčistit a pak do něj přes copy-paste (CTRL+A - CTRL+C -> CTRL+V) vložit některé s zde uváděných mých (nebo Vašich) zdrojáků. Soubory mapping.asm a mapping.inc systém vytvořil automaticky a není doporučeno do nich zasahovat, protože systém je interně přepisuje. Do téhož workspace můžete vkládat více projektů, každý však musí mít svou složku.
Do existujícího workspace pak lze přidávat libovolný počet projektů, pomocí pravého tlačítka myši na kořenové (nejvyšší) větvi stromu "workspace". Podmínkou je, aby každý projekt byl v samostatné složce (adresáři). Do podvětví source files, nebo include files, každého projektu se mohou přidávat další moduly. Další podrobnosti ohledně práce v prostředí ST Visual develop je v tomto manuálu (anglicky).

Nahrání (vypálení) programu do modulu:

RTC Především připojte k modulu vývojové desky STM8S103F3 programátor ST-Link. K tomu jsou určeny čtyři piny na desce vpravo: 3V3, SWIM, GND a NRST (viz obrázek vlevo).
Program lze vypálit přímo z prostředí "ST Visual Dvelopu" takto: v hlavním menu vyberte Build - Build (F7). Pokud překlad a sestavení proběhhne bez chyb, spusťte Debug - Start debugging. Tím se projekt nahraje (vypálí), naskočí okno debuggeru a případně můžete projekt spustit (F5), nebo krokovat (F10).
Vypálit program do STM8 se dá i jednodušeji pomocí ST Visual Programmer, pokud máte k dispozici již "visual developem" přeložený soubor (F7-build, viz výše) *.s19. Tento vznikne v podsložce projektu DEBUG, nebo RELEASE. Otevřete jej přes hlavní menu-File-Open a přes hlavní menu-Program-Current tab program vypálíte. Případně ještě můžete správnost vypálení ověřit pomocí hlavní menu-Verify-Current tab. Další podobnosti odhledně používání ST Visual Programmeru jsou v jeho nápovědě: hlavní menu-Help-Index.

Dúležité upozornění: Zde presentovaný modul mikrokontroléru má výstupy 5V, 3V3 a GND. Na výstupu 5V ve skutečnosti není 5 voltů, ale vstupní napětí, kterým celý tento modul napájíte, buď přes piny +/-, nebo přes konektor mikroUSB, což může být 4.5 - 15V. Buďte opatrní, co k tomu pinu (5V) připojíte, připojovaný modul můžete tímto zničit. Doporučuji modul napájet výhradně z 5V zdroje.

Elektronika, ukázky pro Arduino a STM8, plus programování v Delphi (Lazarusu).

Všechna zapojení modulů v ukázkách (viz elektrická schémata) pracují s velmi malým napětím 3.3V až 12V a neobsahují návod na napájecí zdroj. Pokud se rozhodnete některé z těchto zařízení postavit, důrazně doporučuji používat zdroje s výstupním napětím maximálně 12V, podle schválených norem platných v ČR. Autor návodů za případné škody nepřebírá žádnou odpovědnost.

nahoru