Elektronika, ukázky pro STM8S103F3, plus programování v assembleru.

Čidlo DHT-22 (AM2302) a případně DHT-11

pro měření teploty a vlhkosti

S modulem DHT-22, nebo AM2302 (DHT-11) jsem si pohrál a následující kód pro práci s ním je funkční. Alespoň u mne :-). Časování procesoru je zde nastaveno na 2MHz. CPU rychlost ovlivňuje i čtení z čidla, kde je časování kritické. IO pin zde je PA1. Je možné to samozřejmě změnit. V tomto kodu se čtení z DHT provádí na základě timeru, po spuštění ihned, pak každých cca 15 minut. Při checksum error se čtení opakuje po několika vteřinách. Pokud čidlo nebude komunikovat vůbec, bude po volání čtení nastaven příznak overflow.
Mám v plánu žádat o data přes UART a přečtená data odeslat také na UART. Timer by v tomto případě nebyl potřeba.

Postup pro čtení dat:

Nastavit IO pin na OUTPUT
Shodit jej do LOW na 1ms u DHT-22 (AM2302), nebo 18ms u DHT-11, tím se čidlu pošle žádost o data
Nastavit IO pin na INPUT
Cekat na "start bit" - postupne LOW - HIGH - LOW
Následuje čtení 40 bitů (LOW-HIGH-LOW-HIGH...) - měří se délka stavů HIGH (30us = 0; 70us = 1)
40 bitů = 5 bajtů - vhkost - vlhkost desetiny - teplota - teplota desetiny - kontrolní součet
1.byte + 2.byte + 3.byte + 4.byte AND 0xFF = kontrolni součet, jinak chyba čtení

Tato ukázka kódu je primárně určená pro DHT-22 (AM2302), ale po malé úpravě je možné ji aplikovat i na jednodušší DHT-11. Rozdíl je hlavně v tom, že DHT-22 i AM2302 vrací hodnotu teploty a vlhkosti jako word (2 byte) v destinách stupňů, či procent. U jednodušší DHT-11 vraci u teploty i vlhkosti dva byte, kde první byte jsou celá čísla a druhý byte mají být desetiny. Tyto však obsahují buď nulu, nebo velmi malou hodnotu. Je možné je ignorovat a zobrazovat pouze první byte. Další rozdíl, je ve startovacím LOW impulzu. U DHT-22 i AM2302 má trvat 1 až 2 milisekundy, zatímco u DHT-11 musí být delší, 18 až 20 milisekund. Podrobnosti viz komentáře v kódu.

stm8/

              .form 64
              .tab 10,8,18,60
               TITLE "DHT-22 (AM2302)"

              #include "mapping.inc"

ram0_start.b   equ  $ram0_segment_start
ram0_end.b     equ  $ram0_segment_end
ram1_start.w   equ  $ram1_segment_start
ram1_end.w     equ  $ram1_segment_end	
stack_start.w  equ  $stack_segment_start 
stack_end.w    equ  $stack_segment_end

;-----------------------------------------------------------

CLK_CKDIVR     equ  $50C6 ; CPU rychlost
TIM_CR1        equ  $5300 ; timer 2
TIM_SR1        equ  $5304
TIM_ARRH       equ  $530F
TIM_ARRL       equ  $5310
TIM_PSCR       equ  $530E
TIM_IER        equ  $5303
PA_ODR         equ  $5000  ;PA1
PA_IDR         equ  $5001
PA_DDR         equ  $5002
PA_CR1         equ  $5003
PA_CR2         equ  $5004
PA_PIN         equ  1
UART_SR        equ  $5230
UART_DR        equ  $5231
UART_BRR1      equ  $5232
UART_BRR2      equ  $5233
UART_CR1       equ  $5234
UART_CR2       equ  $5235
DOPPLER_BIT    equ  0
PR_PRECTI      equ  1
DHTOK          equ  7

;-- RAM promenne--------------------------------------------
               segment 'ram0'
							 
zmereno        ds.b     40 ;raw data, pro cteni z DHT
counter        ds.b     1
bit_cnt        ds.b     1
bbyte          ds.b     1
vlh            ds.b     1
vlhdes         ds.b     1
teplota        ds.b     1
teplotades     ds.b     1
checksum       ds.b     1
priznaky       ds.b     1
tiknuti        ds.w     1
stupne         ds.w     1  ;stupne C prevedene pro DHT-22
stupne_des     ds.b     1  ;desetiny stupni
stupne10       ds.b     1
stupne1        ds.b     1
stupne0        ds.b     1  ;znamenko '+ / -'
vlhkost        ds.w     1  ;vlhkost prevedena pro DHT-22
vlhkost_des    ds.b     1  ;desetiny vlhkosti
vlh100         ds.b     1
vlh10          ds.b     1
vlh1           ds.b     1

               segment 'ram1'

;-- PROGRAM ------------------------------------------------
               segment 'rom'

;-- inicializace SETUP -------------------------------------

main.l         mov     CLK_CKDIVR, #$18	   ;cpu rychlost 2 MHz
               sim                         ;zakaz preruseni
               ldw     X, #stack_end
               ldw     SP, X
               ldw     X, #ram0_start                                                                                                                             
clear_ram0.l   clr    (X)
               incw    X
               cpw     X, #ram0_end	
               jrule   clear_ram0
               ldw     X, #ram1_start                                                                                                                             
clear_ram1.l   clr    (X)
               incw    X
               cpw     X, #ram1_end	
               jrule   clear_ram1	            
               ldw     X, #stack_start                                                                                                                             
clear_stack.l  clr    (X)
               incw    X
               cpw     X, #stack_end	
               jrule   clear_stack

              ;mov     UART_BRR2, #$00  ;baud rate 9600 bd, pro 2 MHz CPU, BRR2 musi byt prvni
              ;mov     UART_BRR1, #$0d
              ;bset    UART_CR2,#3      ;povoli TX
              ;bset    UART_CR2,#2      ;povoli RX
               rim
               ldw     X, #10           ;prvni mereni hned

;-- hlavni smycka LOOP -------------------------------------

infinite_loop.l
               call    spust_timer
_cekej0        btjf    priznaky, #PR_PRECTI, _cekej0  ;priznak rizen v IRQ timneru
               bres    TIM_IER, #0             ;zastav timer
               bres    priznaky, #PR_PRECTI    ;pripadne muze byt podle UART
               call    precti               
               jrv     _chyba_dht              ;overflow pri chybe
               call    vypocitej
               jrne   _chyba_dht               ;pokud je checksum ok, je nahozen zero flag
_posli         callr   do_ascii
               callr   odesli
               ldw     X, #9090                ;dalsi meseni za 5 min
               jra     infinite_loop
_chyba_dht     ldw     X, #909                 ;pri chybe za 30 sec opakuj
               jra     infinite_loop
                           
odesli        ;odesla data, zatim nedela nic              
               ret

do_ascii      ;prevede do ascii pouze pro DHT-22, pripravi pro odeslani dat
               callr   preved
               ldw     X, #zmereno
               mov     zmereno, #2             ;STX - start prenosu, pocatek textu
               ld      A, stupne0              ;znamenko
               ld     (1,X), A
               ld      A, stupne10             ;ascii prevod teploty
               or      A, #$30
               ld     (2,X), A
               ld      A, stupne1
               or      A, #$30
               ld     (3,X), A
               ld      A, #'.'                 ;desetinna tecka
               ld     (4,X), A
               ld      A, stupne_des
               or      A, #$30
               ld     (5,X), A
               ld      A, #'C'
               ld     (6,X), A
               ld      A, #';'                 ;oddelovac mezi teplotou a vlhkosti
               ld     (7,X), A
               ld      A, vlh100               ;ascii prevod vlhkosti
               or      A, #$30
               ld     (8,X), A
               ld      A, vlh10
               or      A, #$30
               ld     (9,X), A
               ld      A, vlh1
               or      A, #$30
               ld     (10,X), A
               ld      A, #'.'                 ;desetinna tecka
               ld     (11,X), A
               ld      A, vlhkost_des
               or      A, #$30
               ld     (12,X), A
               ld      A, #'%'
               ld     (13,X), A
               ld      A, #4                   ;EOT - konec prenosu
               ld     (14,X), A                   
               ret
               
preved        ;prevede teplotu a vlhkost pouze pro DHT-22 (u DHT-11 cti primo teplotu i vlhkost bez desetin)
               mov     stupne0, #$2b
               btjf    teplota, #7, _plus      ;bit 7 je znamenkovy 1=zaporna teplota
               mov     stupne0, #$2d           ;zapamatuje znamenko   
               ld      A, teplota              ;a shodi bit7, aby nezkreslil dalsi vypocet
               and     A, #$7F
               ld      teplota, A
_plus          ldw     Y, teplota              ;u DHT22 jde o word real s pevnou
               ld      A, #10                  ;carkou na jedno desetinne misto
               div     Y, A
               ld      stupne_des, A           ;desetiny stupnu
               ldw     stupne, Y               ;stupne C
               ld      A, #10
               div     Y, A
               ld      stupne1, A              ;uloi jednostky stupnu
               ld      A, YL
               ld      stupne10, A             ;ulozi desitky stupnu
               ldw     Y, vlh
               ld      A, #10
               div     Y, A
               ld      vlhkost_des, A          ;vlhkost desetiny
               ldw     vlhkost, Y
               ld      A, #100
               div     Y, A
               push    A
               ld      A, YL
               ld      vlh100, A               ;vlhkost stovky
               pop     A
               ld      YL, A
               ld      A, #10                  
               div     Y, A               
               ld      vlh1, A                 ;vlhkost jednotky
               ld      A, YL
               ld      vlh10, A                ;vlhkjost desitky
               ret
                  
spust_timer   ;timer v X je pocet tiknuti
               ldw    tiknuti, X
               mov    TIM_PSCR, #128
               mov    TIM_ARRH, #255
               mov    TIM_ARRL, #255
               bres   TIM_SR1, #0         ;vymazat update flag
               bset   TIM_IER, #0         ;povolit preruseni
               bset   TIM_CR1, #0         ;spust timer
               ret

;-- DHT-22 -------------------------------------------------
;   rutiny pro cteni DHT-22 (AM2302)

precti        ;precte raw data, 40 bitu z DHT
               bres    priznaky, #DHTOK
               mov     counter, #40
               clrw    Y
               callr   dht_start
               jrv    _dhtchyba
_dalsi         callr   read1bit
               jrv    _dhtchyba
               dec     counter
               jrne   _dalsi
               bset    priznaky, #DHTOK
_dhtchyba      ret

dht_start:    ;zadost o data z DHT
               ldw     X, #zmereno       ;buffer pro vysledky mereni
               callr   set_out           ;PA_PIN ns output
               bres    PA_ODR, #PA_PIN   ;PA_PIN_low      
               ldw     Y, #2000          ;pro DHT-22 cca 2mS podrzet LOW 
_delay1        decw    Y                 ;  (pro DHT-11 18mS, do Y dat 18000)
               jrne   _delay1
               nop
               callr   set_in         ;PA_PIN na input
_cekej1        incw    Y
               jrv    _chyba
               btjt    PA_IDR, #PA_PIN, _cekej1    ;cekej start bit low-high-low
_cekej2        incw    Y
               jrv    _chyba
               btjf    PA_IDR, #PA_PIN, _cekej2    
_cekej3        incw    Y               
               jrv    _chyba
               btjt    PA_IDR, #PA_PIN, _cekej3    
_chyba         ret

read1bit      ;zmeri delhu HIGH a ulozi (jeden bit)
              ;pro CPU 2MHz 0x08 az 0x0D=nula; 0x18 az 0x25=jerdnicka
_cekejh        incw    Y
               jrv    _chyba2
               btjf    PA_IDR, #PA_PIN, _cekejh    ;cekej high
               clr     A
_mereni        inc     A
               nop     ;pro 16MHz CPU jer treba alespon 6 x nop, jinak A pretece
               jrv    _chyba2
               btjt    PA_IDR, #PA_PIN, _mereni    ;merime delku high ctenim do A
               ld      (X), A         
               incw    X
_chyba2        ret

set_out       ;port na output mod
               bset    PA_DDR, #PA_PIN
               bres    PA_CR1, #PA_PIN
               ret

set_in        ;port na input mod
               bres    PA_DDR, #PA_PIN
               bres    PA_CR1, #PA_PIN
               ret

vypocitej     ;prevede raw data do 5 byte
               ldw     X, #zmereno
               callr   cti_byte
               mov     vlh, bbyte
               callr   cti_byte
               mov     vlhdes, bbyte
               callr   cti_byte
               mov     teplota, bbyte
               callr   cti_byte
               mov     teplotades, bbyte
               callr   cti_byte
               mov     checksum, bbyte
               ld      A, vlh
               add     A, vlhdes
               add     A, teplota
               add     A, teplotades
               and     A, #$ff
               cp      A, checksum
               ret

cti_byte      ;naplni byte podle namerenych delek stavu high (raw data)
               mov     bit_cnt, #8 
               clr     bbyte
               jra     _prvnibit
_dalsibit      sll     bbyte
_prvnibit      ld      A, (X)
               incw    X                
               cp      A, #$10   ;pro 2MHz CPU hranice mezi 0/1, pro 16MHz CPU je 0x30 
               jrc     _bitnula  ;pokud je obsah A mensi, nahodi carry = bit v nule
               bset    bbyte, #0
_bitnula       dec     bit_cnt
               jrne    _dalsibit               
               ret
               
;-- konec rutin pro cteni DHT-22 ---------------------------

;---IRQ ----------------------------------------------------

               interrupt timer_interrupt
timer_interrupt.l
               bres   TIM_SR1, #0           ;vymazat update flag
               ldw    Y, tiknuti
               decw   Y
               ldw    tiknuti, Y
               jrne  _preskok
               bset   priznaky, #PR_PRECTI  ;nahod priznak, ze dojel
_preskok       iret

               interrupt NonHandledInterrupt
NonHandledInterrupt.l
               iret

;-- konstanty ----------------------------------------------

;-----------------------------------------------------------
               segment 'vectit'

               dc.l {$82000000+main}                 ; reset
               dc.l {$82000000+NonHandledInterrupt}	; trap
               dc.l {$82000000+NonHandledInterrupt}	; TLI_IRQHandler; External Top Level interrupt
               dc.l {$82000000+NonHandledInterrupt}	; Auto Wake Up from Halt
               dc.l {$82000000+NonHandledInterrupt}	; Clock Controller
               dc.l {$82000000+NonHandledInterrupt}	; EXTI Port A
               dc.l {$82000000+NonHandledInterrupt}	; EXTI Port B
               dc.l {$82000000+NonHandledInterrupt}	; EXTI Port C
               dc.l {$82000000+NonHandledInterrupt}	; EXTI Port D
               dc.l {$82000000+NonHandledInterrupt}	; EXTI Port E
               dc.l {$82000000+NonHandledInterrupt}	; CAN Rx (STM8AF only, N/A on STM8S103)
               dc.l {$82000000+NonHandledInterrupt}	; CAN Tx (STM8AF only, N/A on STM8S103)
               dc.l {$82000000+NonHandledInterrupt}	; SPI
               dc.l {$82000000+NonHandledInterrupt}	; TIM1 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt}	; TIM1 Capture/Compare
               dc.l {$82000000+timer_interrupt}             ; TIM2 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt}	; TIM2 Capture/Compare
               dc.l {$82000000+NonHandledInterrupt}	; TIM3 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt}	; TIM3 Capture/Compare
               dc.l {$82000000+NonHandledInterrupt}	; UART1 Tx complete
               dc.l {$82000000+NonHandledInterrupt}         ; UART1 Rx full
               dc.l {$82000000+NonHandledInterrupt}	; I2C
               dc.l {$82000000+NonHandledInterrupt}	; UART2 (not present on STM8S103)
               dc.l {$82000000+NonHandledInterrupt}	; UART2 (not present on STM8S103)
               dc.l {$82000000+NonHandledInterrupt}	; ADC1 end of conversion
               dc.l {$82000000+NonHandledInterrupt}	; TIM4 Update/Overflow
               dc.l {$82000000+NonHandledInterrupt}	; EEPROM EEC
               dc.l {$82000000+NonHandledInterrupt}	; irq25
               dc.l {$82000000+NonHandledInterrupt}	; irq26
               dc.l {$82000000+NonHandledInterrupt}	; irq27
               dc.l {$82000000+NonHandledInterrupt}	; irq28
               dc.l {$82000000+NonHandledInterrupt}	; irq29

	end

všeobecné informace

U modulů, které jsem v rámci svých možností odladil a otestoval, jsem vytvořil prográmek, který lze formou copy-paste vytáhnout (buď celý, nebo pouze potřebné kusy kódu) a použít jej v nějaké Vaší aplikaci. Zkopírovat se musí potřebný kód, proměnné v paměti a deklarace konstant (equ).

Na stránkách výrobce ST Microelectronics je ke stažení vývojové prostředí ST Visual develop a dále jsou zde velmí podrobné manuály v PDF (v angličtině) odledně popisu mikrokontroléru a jeho instrukčního souboru.

Každý zde uváděný zdroják má stejnou strukturu. Na začátku jsou deklarace adres použitých systémových registrů (UART, I2C, GPIO...), což je klíčové. Tyto adresy jsou popsány jednak v datasheetu STM8, a také jsou k dispozici ve zdrojovém kódu, který je nainstalován spolu s prostředím ST Visual develop ve složce [Program Files]\ STMicroelectronics\ st_toolset\ asm\ include\ STM8S103F.asm). Asi je možné ji deklarovat jako include, ale zde jsou ve zdrojáku definovány pouze ty, které jsou použity.
Dále je inicializační část, kde je vynulována paměť ram, nastaví se rychost CPU a proběhne základní nastavení použitého hardware, například rychlost UARTu, GPIO input/output, atd. Pak už následují rutiny pro konkrétní modul.V nekonečné smyčce infinite_loop je ukázka činnosti. Samotné rutiny lze podle potřeby vykopírovat do jiného projektu. Úplně na konci je tabulka vektorů přerušení v segmentu vectit s popisy, které zařízení může přerušení vyvolat.

Rychlý návod jak vytvořit nový projekt v prostředí ST Visual Dvelop:

V Hlavním menu vybrat File a New workspace.
Zvolit položku Create workspace and project
Objeví se dialog pro zadání skupiny projektů.
Vyplňte pole workspace filename (název skupiny projektů)
Vyyplňte pole workspace location (složka pro umístění)
Naskočí další okno pro projekt.
Vyplňte pole project filename (název projektu)
Vyplňte pole project location (složka pro umístěni projektu, zde doporučuji vybrat podsložku skupiny projektů).
Do pole toolchain vyberte ST Assembler Linker.
Pole toolchain root ponechte nezměněno.
Naběhne výběr pro konkrétní CPU.
Vyberte v něm STM8S103F3P.

Tím se vytvoří projekt. Na levé straně se objeví strom Workspace, kde ve větvi source files otevřete main.asm, které je hlavní zdroják projektu. Je předvyplněn o počáteční definici segmentů a tabulku přerušení. Můžete jej vyčistit a pak do něj přes copy-paste (CTRL+A - CTRL+C -> CTRL+V) vložit některé s zde uváděných mých (nebo Vašich) zdrojáků. Soubory mapping.asm a mapping.inc systém vytvořil automaticky a není doporučeno do nich zasahovat, protože systém je interně přepisuje. Do téhož workspace můžete vkládat více projektů, každý však musí mít svou složku.
Do existujícího workspace pak lze přidávat libovolný počet projektů, pomocí pravého tlačítka myši na kořenové (nejvyšší) větvi stromu "workspace". Podmínkou je, aby každý projekt byl v samostatné složce (adresáři). Do podvětví source files, nebo include files, každého projektu se mohou přidávat další moduly. Další podrobnosti ohledně práce v prostředí ST Visual develop je v tomto manuálu (anglicky).

Nahrání (vypálení) programu do modulu:

RTC Především připojte k modulu vývojové desky STM8S103F3 programátor ST-Link. K tomu jsou určeny čtyři piny na desce vpravo: 3V3, SWIM, GND a NRST (viz obrázek vlevo).
Program lze vypálit přímo z prostředí "ST Visual Dvelopu" takto: v hlavním menu vyberte Build - Build (F7). Pokud překlad a sestavení proběhhne bez chyb, spusťte Debug - Start debugging. Tím se projekt nahraje (vypálí), naskočí okno debuggeru a případně můžete projekt spustit (F5), nebo krokovat (F10).
Vypálit program do STM8 se dá i jednodušeji pomocí ST Visual Programmer, pokud máte k dispozici již "visual developem" přeložený soubor (F7-build, viz výše) *.s19. Tento vznikne v podsložce projektu DEBUG, nebo RELEASE. Otevřete jej přes hlavní menu-File-Open a přes hlavní menu-Program-Current tab program vypálíte. Případně ještě můžete správnost vypálení ověřit pomocí hlavní menu-Verify-Current tab. Další podobnosti odhledně používání ST Visual Programmeru jsou v jeho nápovědě: hlavní menu-Help-Index.

Dúležité upozornění: Zde presentovaný modul mikrokontroléru má výstupy 5V, 3V3 a GND. Na výstupu 5V ve skutečnosti není 5 voltů, ale vstupní napětí, kterým celý tento modul napájíte, buď přes piny +/-, nebo přes konektor mikroUSB, což může být 4.5 - 15V. Buďte opatrní, co k tomu pinu (5V) připojíte, připojovaný modul můžete tímto zničit. Doporučuji modul napájet výhradně z 5V zdroje.

Elektronika, ukázky pro Arduino a STM8, plus programování v Delphi (Lazarusu).

Všechna zapojení modulů v ukázkách (viz elektrická schémata) pracují s velmi malým napětím 3.3V až 12V a neobsahují návod na napájecí zdroj. Pokud se rozhodnete některé z těchto zařízení postavit, důrazně doporučuji používat zdroje s výstupním napětím maximálně 12V, podle schválených norem platných v ČR. Autor návodů za případné škody nepřebírá žádnou odpovědnost.

nahoru